2.6. Designing with OpenSCAD for 3D printing

OpenSCAD is ideal for quickly generating 3d-printable models. Unlike WYSIWYG CAD software, OpenSCAD generates prints programatically. This allows easy design and adjustment of prints based on repetitive patterns using parametric settings.

Note

These notes are based on my experiences with the Prusa i3 Mk3 and Artillery/Evnovo Sidewinder X1 printers. If you are using a different printer, please verify the hardware details are similar.

OpenSCAD is used extensively in the Thingiverse customizer.

These notes are meant to give a taste of OpenSCAD’s capabilities. Please refer to the OpenSCAD online user manual for more details.

Todo

OpenSCAD content

Test parts
Parametric prints

2.6.1. The OpenSCAD user interface

2.6.2. Programming in OpenSCAD

As you adjust the code using OpenSCAD’s programming language, a preview of the resulting model is shown in the view window.

Fig. 2.37 OpenSCAD parametric model example 1

If you adjust parameters or code, pressing the preview button ([F5]) will update the display to show the changes.

Fig. 2.38 OpenSCAD parametric model example 2

2.6.3. Downloadable parametric test prints

2.6.3.1. Bed leveling test

This model is a parametric bed leveling test to be used in conjunction with the Live-Z calibration procedure. It prints a pattern of rectangular shapes in a grid around the print bed, connected by thin lines for easy removal.

Fig. 2.39 Bed leveling test print generated in OpenSCAD

Here’s the source code:

Listing 2.41 Parametric bed level test print

$fn = 90;

t_bed_width = 250;
t_bed_depth = 210;
t_bed_border = 8;
t_shape_xcount = 3;
t_shape_ycount = 3;
t_shape_xsize = 25;
t_shape_ysize = 25;
t_line_width = 1.6;
t_thickness = 0.2;
t_print_width = t_bed_width - t_shape_xsize - (2*t_bed_border);
t_print_depth = t_bed_depth - t_shape_ysize - (2*t_bed_border);

// Bed size
//%square([t_bed_width, t_bed_depth]); 

// Grid area
translate([t_bed_width/2,t_bed_depth/2]){
    %square([t_print_width,t_print_depth], true);
}

// Print area
translate([t_bed_width/2,t_bed_depth/2]){
    %square([t_bed_width-(2*t_bed_border),t_bed_depth-(2*t_bed_border)], true);
}

linear_extrude(height = t_thickness) { 
    // shift everything to center in print area
    translate([(t_shape_xsize/2)+t_bed_border,(t_shape_ysize/2)+t_bed_border,0]){
        // intervals between printed shapes
        t_increment_x = t_print_width / (t_shape_xcount-1);
        t_increment_y = t_print_depth / (t_shape_ycount-1);
        t_center_x = 0;
        t_center_y = 0;
    
        // draw grid
        // draw horizontal lines along X axis
        for(t_curr_x = [0:t_shape_xcount-1]){
            translate([t_center_x, t_print_depth/2, 0]){
                square([t_line_width,t_print_depth], true);
            }
            t_center_x = t_curr_x * t_increment_x;
        }
        // draw vertical lines along Y axis
        for(t_curr_y = [0:t_shape_ycount-1]){
            translate([t_print_width/2, t_center_y, 0]){
                square([t_print_width, t_line_width], true);
            }
            t_center_y = t_curr_y * t_increment_y;
        }
        
        // draw shapes
        t_center_x = 0;
        for(t_curr_x = [0:t_shape_xcount-1]){
            t_center_y = 0;
            for(t_curr_y = [0:t_shape_ycount-1]){
                translate([t_center_x,t_center_y]){
                    square([t_shape_xsize,t_shape_ysize],true);
                }
                t_center_y = t_curr_y * t_increment_y;
            }
            t_center_x = t_curr_x * t_increment_x;
        }
    }
}

Parametric bed level test

2.6.3.2. Test tower

This model is a parametric test tower. It generates a multi-level tower of user-specified dimensions with a divider and label at each level. You can see it in action on the |PS| modifiers page.

Fig. 2.40 Test tower print generated in OpenSCAD

Here’s the source code:

Listing 2.42 Parametric test tower print

$fn = 90;

t_levels = 7; // total number of levels to print
t_start_label = 800; // starting numeric label
t_label = t_start_label; // current level numeric label
t_increment = 100; // increment for text labels on each layer
t_baseheight = 1; // height of base and spacer levels in mm
t_wallheight = 10; // combined height of wall on each layer
t_width = 30; // tower width
t_depth = 25; // tower depth 
t_wallthickness = 1.67; // wall thickness - min. 1.5mm for surface quality & z-seam alignment
t_font = "Open Sans:style=ExtraBold";
t_font_size = t_wallheight*0.6;
t_font_depth = 0.4; // depth of text extrusions
t_solid = true;
t_name = "v20190403";
t_model = "Generic";
t_text_append = "";

module outer_shell() {
    // outer shell
    square([t_width,t_depth], true);
}

module inner_shell() {
    // inner shell is wallthickness thinner
    square([t_width-t_wallthickness,t_depth-t_wallthickness], true);
}

module spacer_shell() {
    // spacer shell is wallthickness thicker
    square([t_width+t_font_depth,t_depth+t_font_depth], true);

}

module print_base(){
    // solid base
    color("goldenrod") {
        linear_extrude(height = t_baseheight) {
            //spacer_shell(); 
                square([t_width+10,t_depth+10], true);
        }
    }
}

module print_spacer(curr_height, fill){
    // elevate to current height
    translate([0,0,curr_height]){
        // spacer layer
        color("gray") {
            linear_extrude(height = t_baseheight) {
                if( fill ) {
                    spacer_shell();
                } else {
                    difference() {
                        spacer_shell(); 
                        inner_shell();
                    }
                }
            }
        }
    }
}

module print_level(curr_height, fill) {
    // elevate to current height
    color("lightblue") {
        translate([0,0,curr_height]){
            linear_extrude(height = t_wallheight) { 
                if( fill ) {
                    outer_shell();
                } else {
                    difference() {
                        outer_shell();
                        inner_shell();
                    }
                }
            }
        }
    }
}

module print_text(curr_height,level_text) {
    // text
    translate([0,-t_depth/2,curr_height]){
        color("wheat"){
            // rotate text upright
            rotate([90, 0, 0]) { 
                // extrude text
                linear_extrude(height = (t_font_depth)) {
                   translate([0,t_wallheight/2,0]){
                            text(level_text,t_font_size,t_font,valign="center",halign="center");
                    }
                }
            }
        }
    }
}

// Generate test tower
// print solid base
print_base();
for(t_level = [0:t_levels-1]){
    // generate levels
    if( t_level == 0 ) {
        // allow for alternate text on 1st (0th) layer
        print_level(t_level, t_solid);
        print_text(t_level,str(t_label,t_text_append));

    } else {
        // generate succeeding layers
        print_spacer(t_level*t_wallheight, t_solid);
        print_level(t_level*t_wallheight, t_solid);        
        print_text(t_level*t_wallheight,str(t_label,t_text_append));
    }
    // update printed label for next layer
    t_label = t_label + (t_level * t_increment);
}

color("red") {
    // print final spacer layer at top of tower
    if(t_solid) {
        difference() {
            print_spacer(t_levels*t_wallheight, t_solid);
            translate([0,0,((t_levels*t_wallheight)+t_baseheight)-t_font_depth]){
                linear_extrude(height = (t_font_depth+1)) {
                    text(t_name,t_font_size*.5,t_font,valign="center",halign="center");
                }
            }
        }
    } else {
        print_spacer(t_levels*t_wallheight, t_solid);
    }
}

Calibration test tower